Abrir Word en la ultima pagina modificada

Más
12 años 11 meses antes #4220 por penetaz
Estimados Señores:
Quisiera saber como puedo abrir un archivo de word de varias paginas y que
cuando lo abra, lo haga justo en la ultima pagina en que me quede, sea
modificada o tan solo revisada es decir, si tengo 100 paginas y
modfificandolo me quede en la 50 cuando lo guarde, lo cierre y despues vuelva
a abrir el mismo archivo me lo abra en la misma pagina 50 que me quede.
Anteriormente tenia en otra maquina instalado el word no me acuerdo que
version era, si 97, 2000 o xp, no lo recuerdo pero que si hacia esa opcion y
ya no tenia que estar perdiendo tiempo buscando donde me quede, sino
automaticamente al abrirlo lo hacia en esa pagina en que me quede, ayuda por
favor como hacerlo, gracias a todos. muchas gracias

--
Gustavots

Por favor, Identificarse o Crear cuenta para unirse a la conversación.

Más
12 años 11 meses antes #4221 por Marta
Hola:
Hasta donde llegan mis conocimientos eso no viene configurado por defecto en ninguna versión de Word.
Lo que se puede hacer es crear una macro que reproduzca ese comportamiento.
Sería algo así:
Sub AutoOpen()
Application.GoBack
End Sub

Lo que hace esta macro es que al abrir el documento te sitúes en la posición
donde se ha producido la última edición en ese documento.

Por favor, Identificarse o Crear cuenta para unirse a la conversación.

Más
4 años 2 meses antes #18632 por Perseverante
Ahora mismo estoy buscando una solución a este problema.
Hay varias cosas por ahí, y como de costumbre muy mal explicadas.

Por favor, Identificarse o Crear cuenta para unirse a la conversación.

Más
4 años 2 meses antes #18633 por Perseverante
la solución de marta no funciona en word 2010


Shift+F5 funciona bien.

He visto que en algunas partes dicen que ya no funciona en word 2013

Shift+F5 viene a equivaler a la función goback

Por favor, Identificarse o Crear cuenta para unirse a la conversación.

Más
4 años 2 meses antes #18634 por Perseverante
En word 2010 me está yendo bien con :

Option Explicit
Sub FileSave()
On Error Resume Next
ActiveDocument.Bookmarks.Add Range:=Selection.Range, Name:="OpenAt"
ActiveDocument.Save
InsertDocTitle
End Sub

Sub FileSaveAs()
On Error Resume Next
ActiveDocument.Bookmarks.Add Range:=Selection.Range, Name:="OpenAt"
Dialogs(wdDialogFileSaveAs).Show
InsertDocTitle
End Sub

Sub AutoOpen()
On Error Resume Next
With ActiveWindow.View
If Err.Number = 4248 Then Exit Sub
.Type = wdPrintView
.Zoom = 100
.TableGridlines = True
End With
ActiveWindow.ActivePane.View.ShowAll = False
ActiveWindow.ActivePane.View.ShowFieldCodes = False
If ActiveDocument.Bookmarks.Exists("OpenAt") = True Then
ActiveDocument.Bookmarks("OpenAt").Select
End If
InsertDocTitle
End Sub

Sub InsertDocTitle()
' Changes window title to include path with filename
Dim NameArray As Variant
Dim NameStringL As String
Dim NameStringR As String
Dim Count As Long
Const maxLen = 120 ' set this value to fit your window width
' (avoid error if no active window)
If Windows.Count > 0 Then
NameStringL = ActiveDocument.FullName
If Len(NameStringL) > maxLen Then
' separate the folder names
NameArray = Split(NameStringL, "\")
' check the folder depth
Count = UBound(NameArray)
If Count > 3 Then
NameStringL = NameArray(0) & "\...\"
NameStringR = NameArray(Count)
Count = Count - 1

' continue adding folders to the left of the string
' until you run out of folders or one won't fit
Do While (Count > 0) And _
(Len(NameStringL) + Len(NameStringR) + _
Len(NameArray(Count)) < maxLen)
NameStringR = NameArray(Count) & "\" _
& NameStringR
Count = Count - 1
Loop

NameStringL = NameStringL & NameStringR
End If
End If

' Change the window's caption
ActiveWindow.Caption = NameStringL
End If
End Sub

Fuente :
answers.microsoft.com/en-us/office/forum...-c4689b3b8018?auth=1

Por favor, Identificarse o Crear cuenta para unirse a la conversación.

Tiempo de carga de la página: 0.336 segundos
Gracias a Foro Kunena